Address Variables

We know when the game ends, but we don't know WHO won. Let's track that.

The address(0) Value:

address(0) is the zero address: 0x0000...0000

We can use it to mean "no winner yet" or "draw".

Adding Winner Tracking:

1. Add a new state variable: address public winner;

2. In startGame, reset it: winner = address(0);

3. In makeMove, when checkWin() is true, set winner = msg.sender; (the player who just moved)

4. When checkDraw() is true, keep winner = address(0); (no winner in a draw)

Add the winner variable and update both startGame and makeMove to track who won.

Add winner tracking

Requirements:

Declares address public winner

Initializes winner in startGame

Sets winner when checkWin is true

Sets winner to address(0) when draw

Winner set before gameOver

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

contract TicTacToe {
    address public playerX;
    address public playerO;

    enum Cell { Empty, X, O }

    Cell[9] public board;

    bool public xTurn;
    bool public gameOver;

    function startGame(address _opponent) public {
        playerX = msg.sender;
        playerO = _opponent;
        xTurn = true;
    }

    function makeMove(uint _position) public {
        require(!gameOver, "Game over");
        require(_position < 9, "Invalid position");
        require(board[_position] == Cell.Empty, "Cell already taken");
        require(xTurn ? msg.sender == playerX : msg.sender == playerO, "Not your turn");

        Cell piece = xTurn ? Cell.X : Cell.O;
        board[_position] = piece;

        if (checkWin()) {
            gameOver = true;
        } else if (checkDraw()) {
            gameOver = true;
        } else {
            xTurn = !xTurn;
        }
    }

    function checkWin() private view returns (bool) {
        // Check rows
        for (uint i = 0; i < 3; i++) {
            if (board[i*3] != Cell.Empty &&
                board[i*3] == board[i*3+1] &&
                board[i*3] == board[i*3+2]) {
                return true;
            }
        }

        // Check columns
        for (uint i = 0; i < 3; i++) {
            if (board[i] != Cell.Empty &&
                board[i] == board[i+3] &&
                board[i] == board[i+6]) {
                return true;
            }
        }

        // Check diagonals
        if (board[0] != Cell.Empty &&
            board[0] == board[4] &&
            board[0] == board[8]) {
            return true;
        }

        if (board[2] != Cell.Empty &&
            board[2] == board[4] &&
            board[2] == board[6]) {
            return true;
        }

        return false;
    }

    function checkDraw() private view returns (bool) {
        for (uint i = 0; i < 9; i++) {
            if (board[i] == Cell.Empty) {
                return false;
            }
        }
        return true;
    }
}